#! /bin/csh -f

# magic and hidden files: Another of the wonders of GMT

/bin/rm -rf	.gmt* 	>& /dev/null

# need lots of sig figs to keep surface from moaning

gmtset D_FORMAT = %.16lg
gmtset ELLIPSOID = Sphere

if ($#argv != 0) then
	echo "usage: $0"
	echo "  example: $0"
	exit
endif

/bin/rm -rf /tmp/* 	 >& /dev/null
/bin/rm -rf ../logs/ 	 >& /dev/null
/bin/rm -rf ../cmTile/ 	 >& /dev/null
/bin/rm -rf ../predTile/ >& /dev/null
/bin/rm -rf ../grd/ 	 >& /dev/null
/bin/rm -rf ../sid/ 	 >& /dev/null
/bin/rm -rf ../jpegs/ 	 >& /dev/null
/bin/rm -rf ../ermapper/ >& /dev/null
/bin/rm -rf ../plots/ 	 >& /dev/null
/bin/rm -rf ../pingMap/  >& /dev/null
    
/bin/mkdir -p	../logs
date		>! ../logs/makeAll.log

set img = '../img/topo.img'

# hardcode arctic bathymetry sid and bounds

set minArctic = 79
set maxPred = 80
set arcticSid = 65535
set arcticGrd = '../arctic/IBCAO_ver2_23_GEO_netCDF_1min_trimmed.grd'
set predOverlap = "$arcticGrd $minArctic $maxPred $arcticSid"

# Next step has to be done by hand for the moment
#getAllCmData				|& cat >> ../logs/makeAll.log

echo; echo "Hard coding arctic grid SID:		 $arcticSid"
echo "Overlap area of predicted and arctic:	-R/-180/180/$minArctic/$maxPred";echo

# the next step is only needed if the SRTM30 is updated 
# or if you want to copy it over again, or something like that
#
#
set palsar = '/palsar'
echo "copying srtm30 DEM from "$palsar" to ../srtm/dem"

if (! -d "$palsar") then
        echo; echo; echo "ERROR: $palsar is not mounted" ; 
	echo; echo; echo "ABORTING..."; echo; echo; exit 1
    endif
 
#rm -rf ../srtm/dem
#cp -r $palsar/DEM/SRTM30/ ../srtm/dem

echo "converting srtm30 DEM to grd"
makeAllDemGrd				|& cat >> ../logs/makeAll.log
echo "done with srtm30 DEM; ok to unmount $palsar"

echo "converting xyzi tracks to xyzi tiles (eg sort into srtm30 tiles)"
makeAllCmTiles $predOverlap 		|& cat >> ../logs/makeAll.log
echo "convert predicted bathymetry from World of Dave to grd"
makeAllPredTiles $img $predOverlap 	|& cat >> ../logs/makeAll.log

echo "median filter pings with predicted depth, and keep track of sid"
makeAllMedian				|& cat >> ../logs/makeAll.log
echo "add srtm30 land data to grd"
makeAllMerged				|& cat >> ../logs/makeAll.log

echo "find locations with at least one ping"
makePingMap $arcticSid			|& cat >> ../logs/makeAll.log

echo "make postscript plots of topography and hit maps"
makeAllPlots				|& cat >> ../logs/makeAll.log
echo "convert postscript in JPEG"
makeAllJpeg				|& cat >> ../logs/makeAll.log

echo "make ERMapper files"
makeAllErmapper				|& cat >> ../logs/makeAll.log

echo "make list of all SID, and search for duplicates"
makeSidLists				|& cat >> ../logs/makeAll.log
echo "For debugging, sort all pings by depth, and by lat, lon, and sid"
makeSorted 				|& cat >> ../logs/makeAll.log

date 					|& cat >> ../logs/makeAll.log